#
#
# ATTENTION : calcul du resultat theorique uniquement dans le
#             cas d un melange """ type_melange= 1 """
#
#



traceEPS(epsI, epsII, epsIII) = epsI + epsII + epsIII
devEPS_I(epsI, epsII, epsIII) = epsI - traceEPS(epsI, epsII, epsIII)/3.
devEPS_II(epsI, epsII, epsIII) = epsII - traceEPS(epsI, epsII, epsIII)/3.
devEPS_III(epsI, epsII, epsIII) = epsIII - traceEPS(epsI, epsII, epsIII)/3.


traceSIG(epsI, epsII, epsIII, E, NU) = 3.*K_ENU(E,NU)*traceEPS(epsI, epsII, epsIII)
devSIG_I(epsI, epsII, epsIII, E, NU) = 2.*G_ENU(E,NU)*devEPS_I(epsI, epsII, epsIII)
devSIG_II(epsI, epsII, epsIII, E, NU) = 2.*G_ENU(E,NU)*devEPS_II(epsI, epsII, epsIII)
devSIG_III(epsI, epsII, epsIII, E, NU) = 2.*G_ENU(E,NU)*devEPS_III(epsI, epsII, epsIII)
SIG_I(epsI, epsII, epsIII, E, NU) = traceSIG(epsI, epsII, epsIII, E, NU)/3. + devSIG_I(epsI, epsII, epsIII, E, NU)
SIG_II(epsI, epsII, epsIII, E, NU) = traceSIG(epsI, epsII, epsIII, E, NU)/3. + devSIG_II(epsI, epsII, epsIII, E, NU)
SIG_III(epsI, epsII, epsIII, E, NU) = traceSIG(epsI, epsII, epsIII, E, NU)/3. + devSIG_III(epsI, epsII, epsIII, E, NU)


set key left top Left reverse
set grid
set xlabel 'temps'
set ylabel 'SIG'
fct_melange(temps_courant) = 1. - 0.6*temps_courant
p   "calcul_princ.maple" u 1:9 t 'hz' w l lc 1 dt 1 lw 2
rep "calcul_princ.maple" u 1:(SIG_I(eps_log($5), eps_log($6), eps_log($7), 100., 0.3)) t 'anal loi 1' w p
rep "calcul_princ.maple" u 1:(SIG_I(eps_log($5), eps_log($6), eps_log($7), 200., 0.45)) t 'anal loi 2' w p
rep "calcul_princ.maple" u 1:(fct_melange($1)*SIG_I(eps_log($5), eps_log($6), eps_log($7), 100., 0.3) + (1.-fct_melange($1))*SIG_I(eps_log($5), eps_log($6), eps_log($7), 200., 0.45)) t 'anal melange' w p
pause -1

set xlabel 'temps'
set ylabel 'eps33/22 / eps11'
p   "calcul_princ.maple" u 1:(eps_log($6)/eps_log($5)) t '22/11' w l lc 1 dt 1 lw 2
rep "calcul_princ.maple" u 1:(eps_log($7)/eps_log($5)) t '22/11' w l lc 3 dt 1 lw 2
pause -1
