# NB ===> 1/3 * (SIG11+SIG22+SIG33) = Spherique_sig
# NB ===> V = v/v0

#volume initial du pti
v0 = 1/8.

K = 1000.
no_potentiel = 4





#potentiel 1 et ses derivees
W_1(V) = K*(1. - (1+log(V))/V)
dWdV_1(V) = K*log(V)/V**2
d2WdV2_1(V) = K*(1.-2.*log(V))/V**3
Ks_approx_1(V) = K/V**2

#potentiel 2 et ses derivees
W_2(V) = (K/2.)*(V - 1)
dWdV_2(V) = K/2.
d2WdV2_2(V) = 0.
Ks_approx_2(V) = 0.5*K/log(V)

#potentiel 3 et ses derivees
W_3(V) = (K/2.)*log(V)**2
dWdV_3(V) = K*log(V)/V
d2WdV2_3(V) = K*(1.-log(V))/V**2
Ks_approx_3(V) = K/V

#potentiel 4 et ses derivees
W_4(V) = (K/2.)*(V - 1)**2
dWdV_4(V) = K*(V - 1)
d2WdV2_4(V) = K
Ks_approx_4(V) = K*(V-1)/log(V)


#CHOIX D UN POTENTIEL => remplacer _i par le numero du potentiel
W(V) = no_potentiel == 1 ? W_1(V) : \
       no_potentiel == 2 ? W_2(V) : \
       no_potentiel == 3 ? W_3(V) : W_4(V)
dWdV(V) = no_potentiel == 1 ? dWdV_1(V) : \
          no_potentiel == 2 ? dWdV_2(V) : \
          no_potentiel == 3 ? dWdV_3(V) : dWdV_4(V)
d2WdV2(V) = no_potentiel == 1 ? d2WdV2_1(V) : \
            no_potentiel == 2 ? d2WdV2_2(V) : \
            no_potentiel == 3 ? d2WdV2_3(V) : d2WdV2_4(V)
Ks_eq189(V) = no_potentiel == 1 ? Ks_approx_1(V) : \
              no_potentiel == 2 ? Ks_approx_2(V) : \
              no_potentiel == 3 ? Ks_approx_3(V) : Ks_approx_4(V)

#pression hydro selon equation 19
moins_p(V) = dWdV(V)
#module secant "exact" = -d(p)/d(V)
Ks(V) = d2WdV2(V)

set xlabel "V - 1"
set ylabel "Spherique sig"
p   "calcul_princ.maple" u ($12/v0 - 1.):5 t 'simulation spherique sig' w lp
rep "calcul_princ.maple" u ($12/v0 - 1.):(moins_p($12/v0)) t 'theorique' w lp
pause -1


set xlabel "temps"
set ylabel "Ks"
p   "derivee_num_Ks" u 1:2 t 'derivee numerique' w lp
rep "calcul_princ.maple" u 1:(Ks($12/v0)) t 'theorique "exact"' w lp
rep "calcul_princ.maple" u 1:(Ks_eq189($12/v0)) t 'theorique equation 189' w lp
pause -1
