#chargement des fonctions communes
load 'gnu_commun'
#chargement des fonctions de la loi MAT_HYPER
load 'gnu_loi_MAT_HYPER'

#domaine de deformation = [-borne_epsL : borne_epsL]
borne_epsL = 0.4
set xrange[-borne_epsL : borne_epsL]
set yrange[-borne_epsL : borne_epsL]

set isosample 25

set xyplane at 0
set xtics axis
set xlabel offset graph 0.65,0,0
set ytics axis
set ylabel offset graph 0,0.65,0
set ztics axis
set zlabel offset graph 0,0,0.65

set xlabel 'epsL 11'
set ylabel 'epsL 22'

#exemple 3D en fonction de epsL 11 et epsL 22
#  (on considere que elongation 3 ne change pas : l3 = 1)
set zlabel 'SIG11 totale'
sp SIG11_W_MAT_HYPER(exp(x),exp(y),1.) w l
#pause -1

#exemple Kt
set zlabel 'Kt'
sp Kt_MAT_HYPER(exp(x),exp(y),1.) w l
#pause -1

#exemple Gt
# (on considere une vitesse elongation l1_point = l2_point = vitesse_l; l3_point = 0)
set zlabel 'Gt'
vitesse_l = 1.
sp  Gt_MAT_HYPER(exp(x),exp(y),1.,vitesse_l,vitesse_l,0.) w l
#pause -1

#exemple trajectoires : epsL_22 = k*epsL_11 ; epsL_33 = 0
epsL_22(epsL_11,k) = k*epsL_11
epsL_22_point(epsL_11_point,k) = k*epsL_11_point
l1(epsL_11) = exp(epsL_11)
l2(epsL_11,k) = exp(k*epsL_11)
l1_point(epsL_11,epsL_11_point) = epsL_11_point*l1(epsL_11)
l2_point(epsL_11,epsL_11_point,k) = epsL_22_point(epsL_11_point,k)*l2(epsL_11,k)
epsL_11_point = 1.
set parametric
set urange[-borne_epsL : borne_epsL]
set vrange[-1. : 1.] #va servir de facteur k

set zlabel 'Kt'
sp  u, epsL_22(u,v), Kt_MAT_HYPER(l1(u),l2(u,v),1.) t '' w l lc 1 dt 1
rep epsL_22(u,v), u, Kt_MAT_HYPER(l2(u,v),l1(u),1.) t '' w l lc 1 dt 1
pause -1

set zlabel 'Gt'
sp  u, epsL_22(u,v), Gt_MAT_HYPER(l1(u),l2(u,v),1.,l1_point(u,epsL_11_point),l2_point(u,epsL_11_point,v),0.) t '' w l lc 1 dt 1
rep epsL_22(u,v), u, Gt_MAT_HYPER(l2(u,v),l1(u),1.,l2_point(u,epsL_11_point,v),l1_point(u,epsL_11_point),0.) t '' w l lc 1 dt 1
pause -1

set zlabel 'NUt'
sp  u, epsL_22(u,v), NU_KG(Kt_MAT_HYPER(l1(u),l2(u,v),1.), Gt_MAT_HYPER(l1(u),l2(u,v),1.,l1_point(u,epsL_11_point),l2_point(u,epsL_11_point,v),0.)) t '' w l lc 1 dt 1
rep epsL_22(u,v), u, NU_KG(Kt_MAT_HYPER(l2(u,v),l1(u),1.), Gt_MAT_HYPER(l2(u,v),l1(u),1.,l2_point(u,epsL_11_point,v),l1_point(u,epsL_11_point),0.)) t '' w l lc 1 dt 1
pause -1
unset parametric
