set terminal pngcairo size 1080,1080

set encoding utf8
set key right top
set tics font ",22"
set xlabel font ",22"
set ylabel font ",22"
set title font ",22"
set key font ",22"

set output "Comparaison_avec_sans_contact.png"
set multiplot

set xrange [0.:0.12]
set xlabel "Déformation [-]"
set yrange [-1.:25.]
set ylabel "Contrainte [MPa]"

set style line 81 lt 0 lc rgb "#808080" lw 2
set grid ytics mytics
set grid xtics mytics
set mxtics 2 
set mytics 2 
set grid

plot "Sans_contact/Simu_insitu_complet_princ.maple" u (1-($89-16)/8):(-$12/955) t "Sans contact" w l lt 1 lw 2, \
	"Avec_contact_chemise/Simu_insitu_complet_contact_princ.maple" u (1-($86-16)/8):($12/955) t "Avec contact chemise" w l lt 2 lw 2, \
	"Experimental/Essais_CD_GEM_essai_2.txt" u 5:6 t "Experimental" w l lt 4 lw 2

unset key
unset title
unset xlabel
unset ylabel
set tics font ",16"

set origin 0.08,0.73
set size 0.4, 0.25
set xrange [0.11: 0.12]
set yrange [20.5: 21.5]
set xtics 0.005
set ytics 0.5
replot

set origin 0.09,0.48
set size 0.4, 0.25
set xrange [0.045: 0.055]
set yrange [7.:8.]
set xtics 0.005
set ytics 0.5
replot

set origin 0.09,0.23
set size 0.4, 0.25
set xrange [0.: 0.01]
set yrange [0.:1.]
set xtics 0.005
set ytics 0.5
replot

unset multiplot
